//  http://www.escoitar.org/spip.php?page=processing_paisaxes_tab05
//  escoitar.tsv

import ddf.minim.*;
 
PFont font;

// CLASES
Timeline timeline;
Place placeSelected;  // Each one of the places selected by the mouse.
Selector zoomSelector;  // The rectangle selector to select the zoom places.
SilenceSpace silenceSpace;
UiSpace uiSpace;
Button zoomOutBtn;
Button infoBtn;
Instructions instructions;
Minim minim;

//ControlP5 controlP5;

// LIST OF THE COLUMNS FROM THE DATA DOCUMENT
String dataDocument = "processing_paisaxes_tab05.tsv";
static final int ID = 0;
static final int X = 1;
static final int Y = 2;
static final int COMARCA = 3;
static final int MP3 = 5;
static final int IMG = 6;
static final int IMGWIDTH = 7;
static final int TITLE = 8;
static final int URL = 9;
static final int AUTOR = 10;
static final int DATE = 11;
static final int IDCATEGORY = 12;
/*
static final int TITLECATEGORY = 13;
*/
// COUNTERS AND ARRAYS
int totalCount;
int placeCount;
Place[] places;

// MAP COORDINATES
float minX, maxX;
float minY, maxY;
float mapX1, mapY1;
float mapX2, mapY2;

//  SPACES VARIABLES
int silenceSpaceX = 560;
int silenceSpaceW = 60;
int timelineSpaceX = 620;
int timelineSpaceW = 250;
int uiSpaceX = 870;
int uiSpaceW = 30;
int sequencerArea = 650;
float distSequencer;
color selectedColor = #ffffff;  //  dark bakground color

boolean overOneDetected = false;  //  switch that changes its value if the mouse is over a place.
boolean doSelector = true;  //  switch used to led zoom selector work only if the mouse is not over a place.
boolean doingSelection = false;  //  switch if we are draging for making zoom.
boolean draggingPlace = false;


// ****************************************************************************
//  SETUP.
// ****************************************************************************
public void setup(){
  frameRate(40);  
  size(900, 600);
  background(0);
  noStroke();  
  smooth();
  font = loadFont("Futura-Medium-48.vlw");
  textFont(font);
  
  //  Sound
  minim = new Minim(this);
  
  mapX1 = 20;
  mapX2 = 530 + mapX1;
  mapY1 = 20;
  mapY2 = 500 + mapY1;

  readData();
  for(int i=0; i<placeCount; i++){
    places[i].draw();
  }  
  
  timeline = new Timeline(timelineSpaceX, timelineSpaceW);
  silenceSpace = new SilenceSpace(silenceSpaceX, 42, silenceSpaceW);
  uiSpace = new UiSpace(uiSpaceX, uiSpaceW);  
  zoomOutBtn = new Button(silenceSpaceX, 0, silenceSpaceW, 20, #102b3b, #1f5473, #3795cc, "Reset", #225d80, #3795cc);  
  instructions = new Instructions(0, 0);
  infoBtn = new Button(silenceSpaceX, 21, silenceSpaceW, 20, #102b3b, #1f5473, #3795cc, "Info", #225d80, #3795cc);
}


// ****************************************************************************
//  DRAW.
// ****************************************************************************
public void draw(){
  background(0);  

if(instructions.isVisible() != true){  
  timeline.update();
  silenceSpace.update();
  uiSpace.update();  
  zoomOutBtn.update();
  zoomOutBtn.display();
  infoBtn.update();
  infoBtn.display();
  
  doSelector = true; // to allow use the selector and reset the initial status.
  
  for(int i=0; i<placeCount; i++){
    if((places[i].selected==true) || (places[i].getPlaying()==true)){ // select only the initial ones, or the ones that were zommed.
      places[i].update();
    }   
  }
  
  for(int i=0; i<placeCount; i++){
    if((places[i].selected==true) || (places[i].getPlaying()==true)){ // select only the initial ones, or the ones that were zommed.

      float closest = 8;
      float d = dist(mouseX, mouseY, places[i].xx, places[i].yy);
      if((d < places[i].radius) && (d < closest) && (overOneDetected==false) && (doingSelection == false)){
        doSelector = false;
        if(draggingPlace==false){
          placeSelected = places[i];
        }  
        closest = d;
        
        placeSelected.loadPicture();
        placeSelected.displayInfoWindow();
        overOneDetected=true;
      }
    }   
  }
  
  overOneDetected=false;  

  if(zoomSelector != null){
    zoomSelector.update();
  } 
}else{  
  instructions.display();
}
}

float TX(float x){
  return map(x, minX, maxX, mapX1, mapX2);
}

float TY(float y){
  return map(y, minY, maxY, mapY2, mapY1);
}

// ****************************************************************************
//  function used for reading the data document.
// ****************************************************************************
void readData(){
  String[] lines = loadStrings(dataDocument);
  parseInfo(lines[0]);  //  read the header line

  places = new Place[totalCount];
  for(int i=1; i<lines.length; i++){
    places[placeCount] = parsePlace(lines[i]);
    placeCount++;
  }
}

// ****************************************************************************
//  function used for PARSING the FIRST LINE of the data file: info line.
// ****************************************************************************
void parseInfo(String line){
  String infoString = line.substring(2);  //  remove the #
  println(infoString);  
  String[] infoPieces = split(infoString, ',');
  totalCount = int(infoPieces[0]);
  minX = float(infoPieces[1]);
  maxX = float(infoPieces[2]);
  minY = float(infoPieces[3]);
  maxY = float(infoPieces[4]);  
}

// ****************************************************************************
// Function used for PARSING the OTHER LINES of the data file.
// ****************************************************************************
Place parsePlace(String line){
  String pieces[] = split(line, TAB);
  int id = int(pieces[ID]);
  float x = float(pieces[X]);
  float y = float(pieces[Y]);
  String comarca = pieces[COMARCA]; 
  String mp3 = pieces[MP3];
  String img = pieces[IMG];
  int imgWidth = int(pieces[IMGWIDTH]);
  String title = pieces[TITLE];
  String url = pieces[URL];
  String autor = pieces[AUTOR];
  String date = pieces[DATE];
  int idCategory = int(pieces[IDCATEGORY]);
  return new Place(id, comarca, x, y, mp3, img, imgWidth, title, url, autor, date, idCategory);
}

// ****************************************************************************
// Mouse interactions.
// ****************************************************************************
void mousePressed(){
  if((doSelector) && (mouseX < silenceSpaceX)){
    placeSelected = null;
    zoomSelector = new Selector(mouseX, mouseY);
    doingSelection=true;
  }else if(mouseX >= silenceSpaceX){
    placeSelected = null;
  }
  if(placeSelected != null){
    draggingPlace = true;
    if(keyPressed && keyCode==SHIFT){
      placeSelected.linkUrl(); 
    }
  }
  //  Scrollbars
  uiSpace.speedControl.press(mouseX, mouseY);
  uiSpace.volumeControl.press(mouseX, mouseY);  
  uiSpace.playBtn.press();
  uiSpace.pauseBtn.press();
  if(uiSpace.playBtn.press()){
    timeline.play();
  }
  if(uiSpace.pauseBtn.press()){
    timeline.stop();
  }  
  if(zoomOutBtn.press()){
    resetZoom();
  } 
  if(infoBtn.press()){
    instructions.setVisible();
  }   
}

void mouseDragged(){
  if(placeSelected != null){
    placeSelected.xx = mouseX;
    placeSelected.yy = mouseY;
    placeSelected.colorNormal = #ffffff;
    placeSelected.colorNormalAlpha = 70;
  } 
}

void mouseReleased(){
  if(placeSelected != null){
    placeSelected.release();
    placeSelected = null; 
    draggingPlace = false;  
  }

  if((zoomSelector != null) && ((zoomSelector.x2 - zoomSelector.x > 10) || (zoomSelector.x - zoomSelector.x2 > 10))){
    zoomSelector.checkCoor();
    for(int i=0; i<placeCount; i++){
      if(places[i].selected==true){
        if((places[i].xx > zoomSelector.x) && (places[i].xx < zoomSelector.x2) && 
        (places[i].yy > zoomSelector.y) && (places[i].yy < (zoomSelector.y + (zoomSelector.x2 - zoomSelector.x)))){
          places[i].xx = map(places[i].xx, zoomSelector.x, zoomSelector.x2 , mapX1, mapX2);
          places[i].yy = map(places[i].yy, zoomSelector.y, zoomSelector.y2 , mapY1, mapY2);
          places[i].i = 40;
        }else{
          places[i].selected=false;
        }
      }
    }
  }
  zoomSelector = null; 
  doingSelection=false; 
  
  uiSpace.speedControl.release();
  if(uiSpace.speedControl.over(mouseX, mouseY)){
    timeline.setInterval(uiSpace.speedControl.getPos());
  }
  uiSpace.volumeControl.release();    
  uiSpace.playBtn.release();  
  uiSpace.pauseBtn.release();  
  zoomOutBtn.release();   
  infoBtn.release();
}

void resetZoom(){
  for(int i=0; i<placeCount; i++){
    if(places[i].getPlaying()==false){
      places[i].selected=true;
      places[i].draw();
    }  
  }
}