/**********************************************/
/* clase para debuxar as xanelas de información
  sobre as paisaxes */
/**********************************************/

class Window extends SoundData{
  color backColor = #ffffff;
  int backAlpha = 220;
  color frontColor = #706e57;
  int backAlpha2 = 150;
  int padding = 15;                   // recheo da venta = padding   
  int wWidth = 300;
  int wHeight = 300;
  int xPos = 82;
  int yPos = 30;
  int [] duracionAumentada;           // duracion de cada paisaxe máis a dos seus anteriores máis os milisegundos
  int [] duracionGlobal;              // duracion de cada paisaxe máis a dos seus anteriores
  int paisaxeSeleccionada;            // almacenamos a id da paisaxe que esta dentro do cronometro
  int paisaxeEsperando;               // paisaxe esperando a ser reproducida trala paisaxe seleccionada
  int xHeadPos;                       // posición da cabeza reproductora 
  int tempo;
  int minutos;
  int minutoAnterior = 0;
  int segundos = 0; 
  int segundoAnterior = 0;
  float volumen;
  String nomeEstado;
  PImage imgToLeft;
  PImage imgToRight;
  PImage imgBoLeft;
  PImage imgBoRight;
  
  Window(int _id, String _ne){
    super(_id);  // envialle o parametro ao constructor de SoundData e permite empregar todas as propiedades da clase.
    nomeEstado = _ne;
    
    duracionAumentada = new int[count];
    duracionGlobal = new int[count];    

    // Calculamos as duracions aumentadas e as duracións globais.
    duracionAumentada[0] = duracion[0];  // na primeira paisaxe, como non pasou tempo antes de que empeze, as duracións son as mesmas.
    duracionGlobal[0] = duracion[0];  
    for(int i=1; i<count; i++){
      duracionAumentada[i] = duracion[i]+duracionAumentada[i-1];
      duracionGlobal[i] = duracion[i]+duracionGlobal[i-1];
    }
    
    //lemos as imaxes que fan as esquinas redondeadas
    imgToLeft = loadImage("imaxes/window/1.png");
    imgToRight = loadImage("imaxes/window/2.png");
    imgBoRight = loadImage("imaxes/window/3.png");
    imgBoLeft = loadImage("imaxes/window/4.png");
  }
  
  //___________________________________________UPDATE____________.
  void update(float _vol){
    volumen = _vol; 
    
    // Averiguamos que paisaxe está soando
    for(int i=0; i<count; i++){
      if(millis() < duracionAumentada[i]){
        paisaxeSeleccionada = i;
        break;
      }
    }
       
    // mapeamos o valor da cabeza reproductora entre 0 e 300
    xHeadPos = int(map(millis(), duracionAumentada[paisaxeSeleccionada]-duracion[paisaxeSeleccionada], duracionAumentada[paisaxeSeleccionada], 0, 300));
    
    // mapeamos os milisegundos entre 0 e a duración da paisaxe
    tempo = int(map(millis(), duracionAumentada[paisaxeSeleccionada]-duracion[paisaxeSeleccionada], duracionAumentada[paisaxeSeleccionada], 0, duracion[paisaxeSeleccionada]));
    
    //pasamos os milisegundos a segundos e minutos (non sei si hai outra forma mellor de facelo...)
    segundos = tempo%60000;
    if(paisaxeSeleccionada != minutoAnterior){
      minutos=0;
    }
    if(segundos < segundoAnterior && paisaxeSeleccionada == minutoAnterior){
      minutos ++;
    }
    segundoAnterior = segundos;
    minutoAnterior = paisaxeSeleccionada;   
  }
  
  //_____________________________________________DRAW____________.
  void draw(){
    if(fase==2){                          // Si xa chegou ao punto de destino
   
      // Debuxamos paisaxe seleccionada == paisaxe sonando 
      noStroke();
      tint(#ffffff, backAlpha);  
      image(imgToLeft, xPos, yPos);                                  //imaxe Top Left
      image(imgBoLeft, xPos, yPos+wHeight+20);                       //imaxe Top Bottom 
      if (imaxe[paisaxeSeleccionada]!=null) {
        image(imaxe[paisaxeSeleccionada], xPos+padding, yPos+50);    //imaxe da paisaxe
      }
      noTint();

      fill(backColor, backAlpha);
      rect(xPos, yPos+20, padding, wHeight);                     // border lateral
      rect(xPos+padding, yPos+20, wWidth+1, 30);                 // border superior
      rect(xPos+padding, yPos+50+100, wWidth+1, wHeight-130);    // fondo
             
      fill(frontColor, backAlpha);
      textSize(16);
      text(nombre[paisaxeSeleccionada], xPos+padding+5, yPos+185);                          // titulo    
      textSize(14);
      text(texto[paisaxeSeleccionada], xPos+padding+5, yPos + 200, wWidth-padding*2, 205);  // descripcion 
      textSize(12);
      text("Grabación " + (paisaxeSeleccionada+1) + " de " + count, xPos+padding*2, yPos+wHeight+20);  // paisaje numero

      // Debuxamos paisaxe esperando
      if(paisaxeSeleccionada==count-1){
        paisaxeEsperando = 0;
      }else{
        paisaxeEsperando = paisaxeSeleccionada+1;
      }
      tint(#ffffff, backAlpha2);  
      image(imgToRight, xPos+wWidth+padding+1, yPos);                    //imaxe Top Right
      image(imgBoRight, xPos+wWidth+padding+1, yPos+wHeight+20);         //imaxe Bottom Right      
      if (imaxe[paisaxeEsperando]!=null) {
        image(imaxe[paisaxeEsperando], xPos+wWidth+padding+1, yPos+50);  //imaxe da paisaxe
      }
      noTint();
      
      fill(backColor, backAlpha2);
      rect(xPos+wWidth*2+padding+1, yPos+20, padding+1, wHeight);    // border lateral
      rect(xPos+wWidth+padding+1, yPos+20, wWidth, 30);              // border superior      
      rect(xPos+wWidth+padding+1, yPos+50+100, wWidth, wHeight-130); // fondo   
             
      fill(frontColor, backAlpha2);
      textSize(16);
      text(nombre[paisaxeEsperando], xPos+wWidth+1+padding*2, yPos+185);                                     // titulo     
      textSize(14);
      text(texto[paisaxeEsperando], xPos+wWidth+1+padding*2, yPos+200, wWidth-padding*2, 205);               // descripcion 
      textSize(12);
      text("Grabación " + (paisaxeEsperando+1) + " de " + count, xPos+wWidth+1+padding*2, yPos+wHeight+20);  // paisaje numero
      
      // Debuxamos cabeza reproductora
      stroke(#FF3700);
      line(xPos+xHeadPos+padding, yPos+70, xPos+xHeadPos+padding, yPos+130);
      
      // Debuxamos info sobre son
      fill(#4D3310, backAlpha);
      text("tiempo: " + minutos + ":" + segundos, xPos+wWidth+80, yPos+35);  // tempo
      text("volumen: " + volumen, xPos+wWidth+190, yPos+35);  // volumen  
      textSize(20);
      text(nomeEstado, xPos+padding, yPos+40);  // nome do estado
    }
  }
  
  void resetTime(){
    for(int i=0; i<count; i++){
      duracionAumentada[i] = duracionGlobal[i] + millis();
    }  
  }
}